I use some scripting in installer packages, but not enough to get
really proficient, so this is a newbie question

To get a value from a reg key I'd use something like:

Set objWshShell = CreateObject("WScript.Shell")
MyValue=objWshShell.RegRead("HKLM\SOFTWARE\MyCompa ny\MyApp
\MyValueName")

But now I need to check if a key is present in the registry whose
values are not known. When the key is present it has a name=value
pair, but the name is random; there is no default (unnamed) value.

How can I check if the key exists or not? (I don't need any of the
values)
thanks!

pooradmin

If I'm following your question right... you can use this to check for
subkeys of a key.

Const HKEY_LOCAL_MACHINE = &H80000002
set owmi = getobject("winmgmts:\\.\root\default:StdRegProv")
strkey = "SOFTWARE"
owmi.enumkey HKEY_LOCAL_MACHINE, strkey, arrKeys

for each okey in arrKeys
wscript.echo okey
next

-J
www.pooradmin.com

mayayana

It sounds like you want to check for any value existing,
but you DID say you want to check for the key,
so here's that:

Dim s1
s1 = "HKCU\Control Panel\Appearance\"
MsgBox Exists(s1)

Function Exists(RegPath)
Dim r, SH
On Error Resume Next
Err.clear
Set SH = CreateObject("WScript.Shell")
r = SH.RegRead(RegPath)
If Hex(Err.number) = "80070002" Then
Exists = False
Else
Exists = True
End If
Set SH = Nothing
End Function

thanks for interpreting my question! .. this is exactly what I need

oops ... it's not quite so ... but thanks to mayayana for the
leads ...

The problem is that mayayana's code returns the same "false" for two
conditions: BOTH when the key is missing AND also when the key exists
but has no default value.

Google found a "real" solution, which actually checks only for the
existence of a key. At http://www.dbforums.com/archive/index.php/t-938413.html


Here's a function that tests for key existence using RegRead that
*may* be
language-independent.

Function KeyExists(ByVal RegKey)
On Error Resume Next
Dim Shell
Dim Description
Set Shell = CreateObject("WScript.Shell")
Shell.RegRead "HKEYNotAKey\"
Description = Replace(Err.Description,"HKEYNotAKey\","")
Err.Clear
RegKey = Replace(RegKey & "\","\\","\") Shell.RegRead RegKey
KeyExists = Description <> Replace(Err.Description,RegKey,"")
End Function

This appears to work in the way I need - checking ONLY whether or not
the KEY exists (and ignoring whether it has values or not)

mayayana

You have to make sure that your string ends with "\"
when checking a key and doesn't end with "\" when
checking a value. It sounds like you checked a key
without the "\" on the end. Your KeyExists function
is designed to *only* check keys. It fails when checking
values because it adds "\" to the string you send in.
But it worked for you because it added the "\".

The function I gave you checks for keys OR values.
Existing values in the key has nothing to do with it.
But you have to write the string properly to indicate
which you're checking.

Aside from that, both functions are doing basically the
same thing. My code checks the error number while
KeyExists checks the error description.


http://www.dbforums.com/archive/index.php/t-938413.html